나눔터  
  HOME > 나눔터 > 묻고답하기 > 엑셀
엑셀
엑셀에 대한 질문과 답변을 올려주세요. 단, 취지에 맞지 않는 글은 운영자가 삭제합니다.
 "000 님, 도와주세요", "부탁 드립니다.", "급합니다!" 등과 같이 막연한 제목을 달지 말아주세요.
[필독] 빠르고 정확한 답변을 얻는 16가지 Tip !
[필독] 저작권법 개정에 따른 이용안내
작성자:  

 dew (dewdrop)

추천:  2
파일:     질문예제(9)_Ans.xlsm (34.4KB) 조회:  1259
제목:   [RE]날짜에 대한 입고량만 가져 올려구 합니다. 도와주세요~!!
     
  * 답변하시는 분들께 도움이 되도록 자신의 환경을 아래 항목 옆에 기재해 주세요.

 - 엑셀 버전(2007):

* 아래줄에 질문을 작성하세요 >>
데이터 시트에 일자별 발주량과 입고량 입고율이 있습니다.여기서...

입고현황 시트에 일자별 각 아이템별 입고량만 가져올수 없나요???

여기 나와있는건 7가지 이지만....   몃천가지아이템 정도 있거등요..  수작업 불가합니다...
그리고 데이터부분은 자동으로 엑셀 변환되는 부분이라서 양식을 건들이지 않고 그대로 두어야 합니다...
==============[전주임님 글에 대한 답변입니다]==============

데이터량이 방대할 경우 VBA로 작업을 하는 것이 좋을 것 같습니다.
첨부화일 참고하세요...

Sub getAmountOfStorage()
    Dim sht As Worksheet, shtDB As Worksheet
    Dim rData As Range
    Dim lRow As Long
    
    Dim rFindGood As Range, rFIndDay As Range, sAddr As String
    Dim sDay As String, sGood As String
    Dim bFound As Boolean
    
    Const sGu As String = "입고"
    
    Set sht = Worksheets("입고현황")
    Set shtDB = Worksheets("DATA")
    Set rData = shtDB.Range("A1").CurrentRegion
    
    For lRow = 6 To sht.Cells(Rows.Count, 2).End(xlUp).Row
        sDay = Day(sht.Cells(lRow, 2)) & "일"
        sGood = sht.Cells(lRow, 3)
        bFound = False
        
        Set rFindGood = rData.Columns(2).Find(What:=sGood, LookAt:=xlWhole)
        If Not rFindGood Is Nothing Then
            Set rFIndDay = rData.Rows(1).Find(What:=sDay, LookAt:=xlWhole)
            If Not rFIndDay Is Nothing Then
                sAddr = rFIndDay.Address
                Do
                    If rFIndDay.Offset(1) = sGu Then
                        bFound = True
                        Exit Do
                    End If
                    Set rFIndDay = rData.Rows(1).FindNext(rFIndDay)
                Loop While Not rFIndDay Is Nothing And sAddr <> rFIndDay.Address
            End If
        End If
        
        If bFound Then
            sht.Cells(lRow, "E") = shtDB.Cells(rFindGood.Row, rFIndDay.Column)
        End If
    Next
End Sub


 
[불량 게시물 신고]  
전주임헐...  엑셀은 수식 밖에 몰랏던... 내안목을...  신세계를 봤습니다. 이거 어케 배우는건가요????  암튼...  쵝오입니다~  ^^  굿잡~05-22 (13:29)
삭제 ■신고
        
  

작성일 : 2019-05-22(09:34)
최종수정일 : 2019-05-22(09:34)
 


 ◎ 관련글

  제 목   작성자   날짜
날짜에 대한 입고량만 가져 올려구 합니다. 도와주세요~!! 전주임 2019-05-21
[RE]날짜에 대한 입고량만 가져 올려구 합니다. 도와주세요~!! dew 2019-05-22