OfficeTutor 365

[뱀]
요즘 보고 있는 책에 내용이 있어서 적어봅니다.
언제 ByVal 또는 ByRef를 사용해야 하는지? 

- 매개 변수를 통해 프로시저 내부로 전달된 변수들을 변경할 필요가 없다면  ByVal을 사용한다.
- 매개 변수를 통해 프로시저 내부로 전달된 변수들을 변경할 필요가 있다면  ByRef를 사용한다.
- 어떤 것을 사용해야 할지 잘 모르는 경우에는 ByVal 키워드를 사용한다.
- VBA는 기본적으로 ByRef를 사용한다. (VB.net에서는 기본적으로 ByVal을 사용) 

ex.
  Sub Main()
    MyValue = 10
    Call ProcessFile(MyValue)
    MsgBox MyValue
  End Sub 

1. ByVal인 경우
  Sub ProcessFile(ByVal YourValue)
    YourValue = YourValue * 10   'YourValue = 100, MyValue = 10
  End Sub 

2. ByRef인 경우
  Sub ProcessFile(ByRef YourValue)
    YourValue = YourValue * 10   'YourValue = 100, MyValue = 100
End Sub
　

[뱀 다리]
 종종 서브프로시저를 호출할 때 전달방식과 관련하여 에러메시지를 볼 것입니다.
"ByRef인수형식이 일치하지 않습니다." 라는... 

이는 전달하려는 값의 데이터 형과 전달 받으려는 서브프로시저의 매개변수의
데이터 형이 다르기 때문입니다. 가령 다음과 같은 프로시져는 에러가 납니다. 

Sub Main()
    Dim i       As Integer   

    i = 100   

    Proc i
End Sub 

Sub Proc(i As Long)
    Debug.Print i
End Sub 

Main에서는 integer형 값을 Proc에 넘겨 주려 합니다. 그러나 Proc에서는 long값만 받죠. 이때 넘겨주는 것은 ByRef이므로 변수의 값이 아니라 변수의 주소입니다. 

VB에서 값은 자동적으로 형변환(캐스팅)되지만 주소는 그런게 없습니다. 따라서 에러가 납니다. 그러므로 두 데이터형중 하나로 통일하거나 또는 전달방식을ByVal로 바꿔야 합니다.
　

[뱀 꼬리]
Sub CallByCallRef() 
  arg1 = 5
  arg2 = 6
  mysub arg1, arg2          '// call by reference
  Debug.Print arg1, arg2    '// results in 1 and 2 

  arg1 = 5
  arg2 = 6
  mysub (arg1), (arg2)      '// call by value
  Debug.Print arg1, arg2    '// results in 5 and 6 

End Sub 

Sub mysub(arg1, arg2)
    arg1 = 1
    arg2 = 2
End Sub